form 输入框
real Start_Time 0.0
real End_Time 0.0 (=all)
positive pitch_Max 600
positive pitch_Min 75
positive maximum_Frequency_for_Formant 5500
positive picture_Width 10
real the_Index_of_referenced_Tier_in_TextGrid 0 (=no referenced TextGrid)
endform
sT=start_Time
eT=end_Time
f0Max=pitch_Max
f0Min=pitch_Min
freFormant=maximum_Frequency_for_Formant
freBMax=5000
freNMax=5000
rTn=the_Index_of_referenced_Tier_in_TextGrid
picWidth=picture_Width
name$= selected$ ("Sound")
if eT=0
eT=Get finishing time
endif
if rTn>0
To TextGrid... PY
#注释：以下暂停以等待使用者进行音节标注，如果不愿意标注，直接按continue 即可，如果标注则等到标注好之后按continue 即可
pause 是否进行音节切分与标注？
select TextGrid 'name$'
tN$=Get tier name... 'rTn'
aI=Is interval tier... 'rTn'
Extract tier... 'rTn'
Into TextGrid
if aI=1
select IntervalTier 'tN$'
Remove
else
select TextTier 'tN$'
Remove
endif
select TextGrid 'name$'
Remove
endif
#注释：以下进行共振峰分析
select Sound 'name$'
To Formant (burg)... 0.01 5 'freFormant' 0.025 50
select Sound 'name$'
To Pitch... 0.01 'f0Min' 'f0Max'
pM=Get mean... 0 0 Hertz
#注释：以下暂停以等待使用者进行基频修改，如果不需要修改，直接按continue 即可，如果修改则等到修改好之后按continue 即可
pause 是否需要调整基频数据？
#注释：以下进行频谱分析（宽带）
select Sound 'name$'
To Spectrogram... 0.005 'freBMax' 0.002 20 Gaussian
#注释：以下进行强度分析
select Sound 'name$'
To Intensity... 100 0
#注释：以下作图
Erase all
#注释：以下得到语音时长
waveTime= Get duration
#注释：以下根据语音时长以确定作图宽度，设计最大宽度为6.5，刚好与Word 默认页面等宽
waveTime= waveTime * 'picWidth'+0.1
if waveTime>6.5
waveTime=6.5
endif
#注释：以下得到宽带语图
Viewport... 0.2 waveTime 0 2
select Spectrogram 'name$'
Paint... 'sT' 'eT' 0 0 100 yes 50 6 0 no
Draw inner box
select Spectrogram 'name$'
Remove
#注释：以下在宽带语图上作共振峰图
Yellow
select Formant 'name$'
Speckle... 0 0 'freBMax' 30 no
Marks left... 6 yes yes yes
Black
Viewport... 0 0.5 0 2
Viewport text... Centre Half 90 Frequency(Hz)
#注释：以下进行窄带分析并作图
select Sound 'name$'
To Spectrogram... 0.03 'freBMax' 0.002 20 Gaussian
Viewport... 0.2 waveTime 1.5 3.5
select Spectrogram 'name$'
freNMax=pM*10
freNMax=freNMax div 100
freNMax=(freNMax+1)*100
Paint... 'sT' 'eT' 0 'freNMax' 100 yes 50 6 0 no
Draw inner box
Marks left... 6 yes yes yes
Black
Viewport... 0 0.5 1.5 3.5
Viewport text... Centre Half 90 Frequency(Hz)
select Pitch 'name$'
pMin=Get minimum... 0 0 Hertz Parabolic
pMax=Get maximum... 0 0 Hertz Parabolic
pMin=pMin-20
pMax=pMax+20
#注释：以下作音高图
Red
Viewport... 0.2 waveTime 3 5
select Pitch 'name$'
Speckle... 'sT' 'eT' 'pMin' 'pMax' no
Marks left... 6 yes yes yes
Draw inner box
Black
Viewport... 0 0.5 3 5
Viewport text... Centre Half 90 Pitch(Hz)
select Intensity 'name$'
iMin=Get minimum... 0 0 Parabolic
iMax=Get maximum... 0 0 Parabolic
iMin=iMin-5
if iMin<40
iMin=40
endif
iMax=iMax+5
#注释：以下作强度图
select Intensity 'name$'
Viewport... 0.2 waveTime 4.5 6.5
Blue
Draw... 'sT' 'eT' 'iMin' 'iMax' no
Marks left... 6 yes yes yes
Draw inner box
Black
Viewport... 0 0.5 4.5 6.5
Viewport text... Centre Half 90 Intensity(dB)
#注释：以下作波形图，如果标注了音节数据，同时会画出音节边界
Black
Viewport... 0.2 waveTime 6 8
select Sound 'name$'
wavMin=Get minimum... 0 0 None
wavMin='wavMin:3'
wavMax=Get maximum... 0 0 None
wavMax='wavMax:3'
Draw... 'sT' 'eT' 0 0 no curve
Draw inner box
One mark left... 0 yes yes no 0
One mark left... 'wavMin' yes yes no 'wavMin'
One mark left... 'wavMax' yes yes no 'wavMax'
Viewport... 0 0.5 6 8
Viewport text... Centre Half 90 Waveform
if rTn>0
select TextGrid grid
Viewport... 0.2 waveTime 6.5 8.5
Draw... 'sT' 'eT' no yes no
Viewport... 0 waveTime 0 8.5
select TextGrid grid
Remove
else
Viewport... 0 waveTime 0 8
endif
#注释：以下将作出的图拷贝到剪贴板，以便能够拷贝到Word 之类的应用程序之中
Copy to clipboard
#注释：以下清除掉临时产生的文件
select Pitch 'name$'
plus Spectrogram 'name$'
plus Formant 'name$'
plus Formant 'name$'
plus Intensity 'name$'
Remove
select Sound 'name$'