#脚本作者：张明辉（北京华睿宝科技有限公司），若您使用此脚本进行学术研究并撰写论文，请在脚注中予以说明或在参考文献中进行援引，多谢支持！
#写作时间：2020年2月14日
#脚本功能：根据已有的TabelOfReal文件的原始共振峰数据（单位：赫兹/Hz），计算两类元音之间的分布重合范围，以此量化彼此的相似程度。
##	共振峰数据范例→以praat内置的荷兰语元音数据为例，依次点击praat主窗口new/tables/creat tableofreal(pols 1973)，得到一个TableOfReal文件，将之保存，后期即可利用它替换成自己所需的共振峰数据
#联系：若有任何疑问，或脚本需要debug，请添加本人微信zhangxiaojian160408进行联系

form
	word vowelA 
	word vowelB 
	integer sigma 2
	choice Covariance_Matirx: 1
		button Group covariance matrix
		button Pool covariance matirx
endform

if covariance_Matirx = 1
	c$ = "no"
else
	c$ = "yes"
endif

hertzData$ = selected$("TableOfReal")
barkData = Copy: "barkData"
Formula: ~ hertzToBark (self)
discriminant = To Discriminant

selectObject: barkData
Extract rows where label: "is equal to", vowelA$
nVowelA = Get number of rows
Remove


selectObject: barkData
Extract rows where label: "is equal to", vowelB$
nVowelB = Get number of rows
Remove

nAplusB = nVowelA + nVowelB
selectObject: barkData, discriminant
t1 = To TableOfReal (mahalanobis): vowelA$, c$
selectObject: barkData, discriminant
t2 = To TableOfReal (mahalanobis): vowelB$, c$

tr = Copy: "tr"
Formula: ~ object [t1] < sigma and object [t2] < sigma

selectObject: tr
num = Get number of rows
nOverlap = 0
nA = 0
nB = 0

for i from 1 to num
	overlap = Get value: i, 1
	if overlap = 1
		label$ = Get row label: i
		if label$ = vowelA$ or label$ = vowelB$
			nOverlap = nOverlap + 1
		endif
		if  label$ = vowelA$
			nA = nA + 1
		endif
		if  label$ = vowelB$
			nB = nB + 1
		endif
	else
		nOverlap = nOverlap
	endif	
endfor

similarA = (nA/nVowelA) * 100
similarB = (nB/nVowelB) * 100

select all
minusObject: "TableOfReal 'hertzData$'"
Remove
selectObject: "TableOfReal 'hertzData$'"

echo 元音'vowelA$'有'nVowelA'个样本，元音'vowelB$'有'nVowelB'个样本，两者之间有'nOverlap'个样本分布范围重合，其中:'newline$''newline$'①元音'vowelA$'有'nA'个样本与元音'vowelB$'重合，占比约'similarA'%;'newline$''newline$'②元音'vowelB$'有'nB'个样本与元音'vowelA$'重合，占比约'similarB'%